*------------------------------------------------------------------------------
*
* Filename             : TEST.F
*
*==============================================================================
*
* Description : Example program to simulate 'thermal' spectra in AA collisions 
*               at LHC with HYDRO-code (should be compiled with hydro.f and 
*               jetset_73.f with extended size of common block LUJETS) 
*==============================================================================

       real A, bmin, bmax, bfix 
       integer ifb, ny  
       external ludata 
       common /lujets/ n,k(150000,5),p(150000,5),v(150000,5)
       common /pawc/ hmemor(20000)
       common /hyfpar/ bgen
       common /hyflow/ ytfl 

* prepare hbook memory 
       call hlimit(20000)
* open hrout file to write histograms 
       call HROPEN(1,'HISTO','hydro.hrout','N',1024,ISTAT)
* prepare hbook histograms 
       call hbook1(1,'dN/dy $',100,-10.,10.,0.)      ! rapidity 
       call hbook1(2,'dN/deta $',100,-10.,10.,0.)    ! pseudorapidity 
       call hbook1(3,'dN/dpt $',100,0.,10.,0.)       ! transverse momentum  
       call hbook1(4,'dN/dphi $',100,-3.15,3.15,0.)  ! azimuthal angle 
       call hbarx(0)

* set initial beam parameters 
       A=207.                             ! atomic weigth        
       ny=3000                            ! <dN(ch)/dy> at y=0 for central Pb-Pb 
c       ifb=0                              ! fixed impact parameter
c       bfix=0.                            ! in nucleus radius units
       ifb=1                              ! distribution over impact parameter  
       bmin=0.                            ! from 'bmin' 
       bmax=1.                            ! to 'bmax'  

* set strength of transverse flow              
       ytfl=1.                            ! maximum transverse flow rapidity

* set number of generated events 
       ntot=10 
       
       do ne=1,ntot                        ! cycle on events 
        call hydro(A,ifb,bmin,bmax,bfix,ny)! single 'thermal' event generation  
               
        do ip=1,n                          ! cycle on particles        
         pt=plu(ip,10)                     ! transverse momentum... 
         ycm=plu(ip,17)                    ! rapidity...  
         eta=plu(ip,19)                    ! pseudorapidity...  
         phi=plu(ip,15)                    ! azimuthal angle... 
         charge=plu(ip,6)                  ! electric charge  
           	 
* fill histograms for charged particles 
         if(abs(charge).gt.0.) then 
          call hfill(1,ycm,0.,1.)          ! rapidity    
          call hfill(2,eta,0.,1.)          ! pseudorapidity 
          call hfill(3,pt,0.,1.)           ! transverse momentum 
          call hfill(4,phi,0.,1.)          ! azimuthal angle    
         end if 
        end do 
        write(6,*) 'Event #',ne
        write(6,*) 'Impact parameter',bgen,'*RA',' Total multiplicity',n  
        write(6,*) '***************************************************' 
       end do 
 
* finish histograms writing procedure        
       call hidopt(0,'ERRO')
       call histdo
       CALL HROUT(0,ICYCLE,' ')
       CALL HREND('HISTO')
       
       end
*******************************************************************************